Odpowiedz
Autor Wiadomość
Nie podano
PostWysłany: 01 Maj 2009, 21:06 
Dołączenie:
Luty 2009
Posty: 5
Witam !

Potrzebuje skryptu ktory zmienialby na jednoprimowym obiekcie (podlodze) co jakis czas teksture /tekstury byly wrzucone do obiektu / jesli ma tos taki skrypt bardzo prosilbym o umieszczenie go w temacie :)

Dziekuje z gory i pozdrawiam.


Profil E-mail Offline
Nie podano
PostWysłany: 01 Maj 2009, 22:04 
Administrator
Awatar użytkownika
Dołączenie:
Kwiecień 2007
Posty: 6356
nick w SL: Madelaine Sautereau
http://www.secondlife.pl/viewtopic.php?t=4876


Profil E-mail Offline
Nie podano
PostWysłany: 02 Maj 2009, 00:16 
Awatar użytkownika
Dołączenie:
Maj 2007
Posty: 2318
nick w SL: Morrigan Polanski
Mad, w tamtym temacie chodziło o coś zgoła innego.

Cytuj:
// PictureBoard Script
// Display pictures from any user via ctrl-drag onto object.
// Original script by Cienna Rand

// Chat commands:
// next : advance to next picture
// back : go back to previous picture
// slide N : advance automatically every N seconds (slideshow)
// slide 0 : stop slideshow mode
// purge : (owner only) purge dropped textures from inventory of board

// Config Items
// If TRUE, show name of image above the board, FALSE for no name
integer showText = FALSE;
// If showText is TRUE, text shown will be in this color
vector textColor = <1,1,1>;

// SCRIPT BEGINS - Do not modify unless you know what you're doing //
integer curr = 0;
list contents = ["Blank"];

setText(string text)
{
if (showText)
llSetText(text, textColor, 1.0);
}

purge()
{
integer i = 0;
integer n = llGetInventoryNumber(INVENTORY_TEXTURE);
while (n > i)
{
string name = llGetInventoryName(INVENTORY_TEXTURE, i);
if (name != "Blank")
llRemoveInventory(name);
else
i++;
n = llGetInventoryNumber(INVENTORY_TEXTURE);
}
curr = 0;
contents = ["Blank"];
llSetTexture("Blank",1);
llSetText("", <1,1,1>, 1.0);
}

back()
{
if (llGetListLength(contents) == 1) return;
if (curr == 1) curr = llGetListLength(contents) - 1;
else curr--;

setText(llList2String(contents, curr));
llSetTexture(llList2String(contents, curr), 1);
}

next()
{
if (llGetListLength(contents) == 1) return;
if (curr == llGetListLength(contents) - 1) curr = 1;
else curr++;

setText(llList2String(contents, curr));
llSetTexture(llList2String(contents, curr), 1);
}

help()
{
llWhisper(0, "Say 'next' to advance to the next picture.");
llWhisper(0, "Say 'back' to go back to the previous picture.");
llWhisper(0, "Say 'slide N' to automatically advance every N seconds (ex: slide 5)");
llWhisper(0, "Say 'slide 0' to stop slide show mode.");
llWhisper(0, "Owner only: say 'purge' to clear textures from board's inventory.");
}

default
{
state_entry()
{
purge();
llListen(0, "", "", "");
llAllowInventoryDrop(TRUE);
llSetColor(<0.2,0.2,0.2>, ALL_SIDES);
llSetColor(<1,1,1>, 1);
}

on_rez(integer param)
{
llWhisper(0, "Say 'help' for commands.");
}

changed(integer change)
{
if ((change & CHANGED_INVENTORY) || (change & CHANGED_ALLOWED_DROP))
{
integer count = llGetInventoryNumber(INVENTORY_TEXTURE);
if (count > llGetListLength(contents)) // New Texture
{
integer i;
for (i = 0; i < count; i++)
{
string name = llGetInventoryName(INVENTORY_TEXTURE, i);
if (llListFindList(contents, [name]) == -1)
{
contents += name;
jump break;
}
}
@break;
curr = llGetListLength(contents) - 1;
string name = llList2String(contents, -1);
setText(name);
llSetTexture(name, 1);
}
}
}

listen(integer channel, string name, key id, string msg)
{
if (id == llGetOwner() && msg == "purge")
{
llWhisper(0, "Purging textures from my inventory.");
purge();
}
else if (msg == "back")
{
back();
}
else if (msg == "next")
{
next();
}
else if (msg == "help")
{
help();
}
else if (llGetSubString(msg, 0, 4) == "slide")
{
llSetTimerEvent((float)llGetSubString(msg, 6,-1));
}
}

timer()
{
next();
}
}


Profil E-mail Offline
Nie podano
PostWysłany: 02 Maj 2009, 01:05 
Administrator
Awatar użytkownika
Dołączenie:
Kwiecień 2007
Posty: 6356
nick w SL: Madelaine Sautereau
Morri, ja nie mam licencji na nieomylność ;-) Podrzucam linki, które wydają mi się podobne.

P.s. Zgoła? Ja wiem, że ciepło się zrobiło, ale bez przesady 8-)


Profil E-mail Offline
Nie podano
PostWysłany: 02 Maj 2009, 01:08 
Awatar użytkownika
Dołączenie:
Maj 2007
Posty: 2318
nick w SL: Morrigan Polanski
Uwielbiam takie dziwnostki ;)
Zgoła, azali, zawżdy i takie tam.


Profil E-mail Offline
Nie podano
PostWysłany: 02 Maj 2009, 01:57 
Dołączenie:
Lipiec 2008
Posty: 3307
nick w SL: MaxJames Chemistry
Ja gdzieś mam skrypt nieco prostszy, który co parę sekund zmienia teksturkę na obiekcie. Trzeba jedynie go lekko zmodyfikować, aby sprawdzał, ile jest tekstur w obiekcie, bo akuralnie ma on zpaodane UUID tekstur, które są full perm.


Profil E-mail Offline
Nie podano
PostWysłany: 02 Maj 2009, 06:53 
Dołączenie:
Luty 2009
Posty: 5
Dziekuje za pomoc !

Morrigan mozesz jeszcze napisac jak zaczac uzywac tego skryptu poniewaz samo wrzucenie tekstur i dodanie skryptu narazie nie wiele mi dalo :)

Dziekuje i pozdrawiam :)


Profil E-mail Offline
Nie podano
PostWysłany: 02 Maj 2009, 13:44 
Awatar użytkownika
Dołączenie:
Maj 2007
Posty: 2318
nick w SL: Morrigan Polanski
Przecież wszystko jest w komentarzach. Wpisujesz w czacie np. slide 30 i tekstura zmienia się co 30 sekund. W linijkach poprzedzonych //znajduje się komentarz do skryptu wyjaśniający jego działanie i listę komend. Postaw prima, wsadź skrypt, potem trzymając Ctrl przeciągaj tekstury na prima. Komendą slide zmieniamy czas wyświetlania teksturki, next i back ręcznie ustawia kolejną lub poprzednią.


Profil E-mail Offline
Nie podano
PostWysłany: 02 Maj 2009, 13:50 
Awatar użytkownika
Dołączenie:
Sierpień 2007
Posty: 2632
nick w SL: WoodPaker Barbosa
Zgos sie do Szerwpa tak jak Ci poradzilem na PW i popros go o ten skrypt. Bosh.. Tam mozesz sbie ustawic, ktora tekstura jak dlugo ma byc "pojawiona"
Pozdrawiam


Profil E-mail Offline
Nie podano
PostWysłany: 03 Maj 2009, 07:29 
Dołączenie:
Luty 2009
Posty: 5
Dziekuje wszystkim za pomoc i pozdrawiam :) !


Profil E-mail Offline

Wyświetl posty z poprzednich:  Sortuj według  

Odpowiedz



Kto jest na forum

Użytkownicy przeglądający to forum: Brak zarejestrowanych użytkowników oraz 4 gości

Panel
Góra
Skocz do:  
SecondLife.pl designed by CvX! Powered by phpBB © phpBB Group - tłumaczenie
SecondLife.pl nie jest oficjalną stroną Second Life. SecondLife.pl is an unofficial Second Life website. SecondLife, SL logo and Second Life related graphics are trademarks of Linden Lab.

Entropia Universe , Planet Calypso